Xiao ESP32-C6 & ADS1292R: SPI issue

msfujino · April 12, 2025, 10:13pm

megamoser,
I’m glad it works for now.

The Technical Reference Manual “27 SPI Controller(SPI)” especially “GP-SPI2” is helpful.
The ESP32 SPI is a bit different. Try VSPI at the link below, you may not need to change the MISO, MOSI, and SCLK pins.

github.com/espressif/arduino-esp32

libraries/SPI/examples/SPI_Multiple_Buses/SPI_Multiple_Buses.ino

master



/* The ESP32 has four SPi buses, however as of right now only two of
 * them are available to use, HSPI and VSPI. Simply using the SPI API
 * as illustrated in Arduino examples will use VSPI, leaving HSPI unused.
 *
 * However if we simply initialize two instance of the SPI class for both
 * of these buses both can be used. However when just using these the Arduino
 * way only will actually be outputting at a time.
 *
 * Logic analyzer capture is in the same folder as this example as
 * "multiple_bus_output.png"
 *
 * created 30/04/2018 by Alistair Symonds
 */
#include <SPI.h>

// Define ALTERNATE_PINS to use non-standard GPIO pins for SPI bus

#ifdef ALTERNATE_PINS

This file has been truncated. show original

msfujino · April 12, 2025, 11:55pm

I read the chip ID on the BMP388. I was able to read the ID without any problem with either regular SPI or VSPI.

#include <SPI.h>

#define CS    D3

SPISettings settings(1000000, MSBFIRST, SPI_MODE0);

void setup() {
  Serial.begin(115200);
  while (!Serial);
  Serial.println("Register Read TEST");

  pinMode(CS, OUTPUT);
  digitalWrite(CS, HIGH);

  SPI.begin();
}

void loop() {
  Serial.println("Send command...");
    SPI.beginTransaction(settings);
    digitalWrite(CS, LOW);   
    SPI.transfer(0x80);   // BME388: 0x80 0x00
    SPI.transfer(0x00);

  Serial.println("Reading register...");  
    uint8_t readByte = SPI.transfer(0xFF);
    digitalWrite(CS, HIGH);
    SPI.endTransaction();

  Serial.print("0x");
  Serial.println(readByte, HEX);

  delay(1000);
}

#include <SPI.h>

// XIAO ESP32C3 uses VSPI
#define VSPI_MISO   MISO    // D9
#define VSPI_MOSI   MOSI    // D10
#define VSPI_SCLK   SCK     // D8
#define VSPI_SS     D3      // CS
#define VSPI        FSPI

SPIClass * vspi = NULL;

void setup() {
  Serial.begin(115200);
  while (!Serial);
  Serial.println("Register Read TEST");

  vspi = new SPIClass(VSPI);
  vspi->begin(VSPI_SCLK, VSPI_MISO, VSPI_MOSI, VSPI_SS); //SCLK, MISO, MOSI, CS
  pinMode(vspi->pinSS(), OUTPUT); //VSPI CS

}

void loop() {
  Serial.println("Send command...");
    vspi->beginTransaction(SPISettings(1000000UL, MSBFIRST, SPI_MODE0));
    digitalWrite(vspi->pinSS(), LOW);
    vspi->transfer(0x80);   // BME388: 0x80 0x00
    vspi->transfer(0x00);

  Serial.println("Reading register...");  
    uint8_t readByte = vspi->transfer(0xFF);
    digitalWrite(vspi->pinSS(), HIGH);
    vspi->endTransaction();

  Serial.print("0x");
  Serial.println(readByte, HEX);

  delay(1000);
}