XIAO ESP32C3 and I2S. How to?

Products & Technology XIAO
21

Using the MAX98357A I2C decoder and amp with GitHub - pschatzmann/arduino-audio-tools: Arduino Audio Tools (a powerful Audio library not only for Arduino)
and the following pins:

#if defined(SEEED)
  cfg.pin_data = D2;
  cfg.pin_bck = D1;
  cfg.pin_ws = D0;
#endif

It works perfectly. Even streaming seems faultless if you don’t have the logging maxed out.

Seeed has not fabbed their own version, it’s just a stock espressif part in the can:
I doubt their ‘engineer’ commenting on this had anything to do with this part. It’s very well done.

Imgur

22

Have a look at that:

23

@Rob_Fowler could you please provide the code that you used to achieve playable audio stream for the ESP32-C3?

I have designed a PCB board which when using the ESP32-I2S library is really choppy and not playable. I want to fetch the live stream audio and playback it to the amp. Any code that you can provide would be helpful.

Thanks!

24

I used this. Plays an mp3 stream with an mqtt command.

25

Thank you for your reply.

I have found some other code on the official wiki page of the Arduino Audio Tools.

For everyone wondering I can confirm that live MP3 stream works perfect on the C3.

Thank you once again @Rob_Fowler for your guidence. I almost lost hope until I found your post :blush:

26

Hi, sorry I couldn’t respond sooner. Basically everything is in this thread except that I was using this:
https://github.com/schreibfaul1/ESP32-audioI2S

As I said previously, on a C3 chip it is choppy at the speed most internet radio stations stream but at a lower bit rate it can cope. The one issue I did come across (and its a while since I did anything with this) that Adafruit provided an “Audio” routine as part of their development pack and although it says its only for a specific device type the internal parameter settings said it was for all device types and Arduino IDE was selecting that instead.

If its any consolation the S3 version works just fine but you must use the correct pins - also documented elsewhere in this thread.

Best of luck.

27

Just looked through the code - he uses the pschatzmann git library mention elsewhere in the thread.

28

Hello Guys,
Thank to all people that wrote information on this thread. With your help, I managed to make my idea work.

I was able to mount a Xiao ESP32-C3 with a Adafruit ADA5769 head to tail and to make them play an mp3.

I had to modify the existing exemple from the Arduino Audio Tools library, the default pins were not the good ones :

/**
 * @file player-sd-i2s.ino
 * @brief example using the SD library
 * 
 * @author Phil Schatzmann
 * modified by Jean-Rodolphe Letertre to adapt a Xiao ESP32-C3 with an Adafruit ADA5769 I2S (Max 98257)
 * @copyright GPLv3
 */

// defining pins

// SPI pins for SD card on the ADA5769 card
// we use the numbers of the GPIO Pins
#define SCK_PIN 8
#define MISO_PIN 9
#define MOSI_PIN 10
#define CS_PIN 2

// I2S Pins
// GPIO numbers here too
#define BCK_PIN 5
#define WS_PIN 4
#define DATA_PIN 3

#include "SPI.h"

#include "AudioTools.h"
#include "AudioTools/AudioLibs/AudioSourceSD.h"
#include "AudioTools/AudioCodecs/CodecMP3Helix.h"

const char *startFilePath="/";
const char* ext="mp3";

AudioSourceSD * source;
I2SStream i2s;
MP3DecoderHelix decoder;
AudioPlayer * player;

void playFile(String filename)
{
  char * filter;
  filter = new char [filename.length()+3];
  // had to do this because c_str was messing with adding '*' at beginning and end of the string (why ?)
  filter[0] = '*';
  for (int i = 0; i < filename.length(); i++)
    filter [i+1] = filename[i];
  filter [filename.length()] = '*';
  filter [filename.length()+1] = 0x00;
  Serial.println(filter);
  source->setFileFilter(filter);
  player->begin();
  delete [] filter;
}

void soundAndSDInit()
{
  // we initialise the SPI bus with the pins specified at the begining of the file
  SPI.begin(SCK_PIN, MISO_PIN, MOSI_PIN, CS_PIN);
  // we initialize the SD audio Source, adding the CS_PIN and the SPI initialised
  source = new AudioSourceSD (startFilePath, ext, CS_PIN, SPI);
  // we initialize the audio player with this audio source and the decoder
  player = new AudioPlayer (*source, i2s, decoder);
  
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);

  // We create a default config
  auto cfg = i2s.defaultConfig(TX_MODE);
  // in which we modify the pins for I2S connection
  cfg.pin_bck = BCK_PIN;
  cfg.pin_ws = WS_PIN;
  cfg.pin_data = DATA_PIN;

  // we initialise the I2S bus with the modified config
  i2s.begin(cfg);
}

void processSound()
{
  player->copy();
}

The setup and loop main program looked like this (I added too some bluetooth code that receives the file filename throught BT and then play it) :

extern bool flagMsgRecvd;
extern String RXMsg;


void setup()
{
  Serial.begin(115200);
  blueToothInit();
  soundAndSDInit();
  delay(1000);
}

void loop()
{
  manageBT();
  
  if (flagMsgRecvd)
  {
    flagMsgRecvd = false;
    playFile(RXMsg);
  }
  processSound();
}

If it can help some others.

1 Like